How to code this?

[jar_output_error]

The easiest to code would be a choice. Although you could convert this to a tappable. It’s the COUNT character that determines how many points the reader gets.

@COUNT =0
@CARTER =0
@REMI =0
label suspect_choice
        NARRATOR
    Okay then, who do you think did it?
choice
"The weaselly guy in red." if (CARTER=0){
@COUNT +1
@CARTER +1
        NARRATOR
    No, wrong, try again.
goto suspect_choice
}
<LOCKED>"The weaselly guy in red." if (CARTER>0){
goto suspect_choice
}
"The girl in the flower dress." if (REMI=0){
@COUNT +1
@REMI +1
        NARRATOR
    No, wrong, try again.
goto suspect_choice
}
<LOCKED>"The girl in the flower dress." if (REMI>0){
goto suspect_choice
}
"The mysterious stranger."{
@COUNT +1
        NARRATOR
    Well duh, so obvious!
goto end_suspect_choice
}

label end_suspect_choice
if (COUNT = 1){
@HERO +2
readerMessage +2 hero points!!!
        NARRATOR
    That was excellent!
}
elif (COUNT = 2){
@HERO +1
readerMessage +1 hero point.
        NARRATOR
    That was okay... I guess.
}
else{
readerMessage That was so bad, I can't even look at you right now.
        NARRATOR
    That was just awful.
}